تعلم تأثير اغلاق النوافذ مع فلاش 8 الجديد كما في ويندوز فيستا ولينكس بالاكشن سكربت 2

[Akwad Net]

اهلين اخي زيزوار بالفعل قمت بتنفيذ العملية على النسخة الثانية من النافذه وهي تقوم بالتأثير نفسة والسحب
حاليا اقوم بعمل تاثير التشويش عند الضغط على النافذه ...
بعد قليل سوف اقوم بإدارجة
اشكرك على تواصلك يا معلمنا

[Akwad Net]

النسخة الثالثة من النافذة المشوشة
كيف الاسم ؟؟
طبعا تم اضافة تأثير تشويش على النافذه وتم اضافة فنكشن جديد حلوو للتشويش عند الضغط على زر الدراج او السحب للنافذة
سميت الفنكشن onDrage(num) وحطينا فيه براميتر اسمه Num عشان نطبق التأثير او نلغي التأثير عند الضغط على عمود السحب .. هذا هو الكود الجديد طبعا .. مع الفنكشن المضاف للنسخة الثالثة

// May peace and Allah Mercy and Blessings be upon you,
// closing flash window with Blur Effect like linux windwos :D:D
/// by akwad Net
//www.akwad.net

myWidth = this._width;// getting width of the movie Clip
myHeight = this._height;// getting height of the movie Clip
_root.add_btn._visible = false;/// hdie the root bottun when this movie show
import flash.filters.DropShadowFilter;// importing the DropShadowFilter filter class
import flash.filters.BlurFilter;// importing the blur filter class
var myShadow:DropShadowFilter = new DropShadowFilter(4, 45, 0x333333, 0.4, 10, 10, 2, 3);///drop Shadow filtter settings
var myBlure:BlurFilter = new BlurFilter(55, 100, 3);// setting of the blur fillter
background_mc.filters = [myShadow];// adding the dropShadow Fillter to the backGround Movie
this._visible = false;// visiabling this window when attach to the Root
this._alpha = 0;
showMe();//Call Start effect Function
function onDrage(num) {
    this.onEnterFrame = function() {
        filters = [myBlure];// assign fillter to this movieClip
    if (num == 1) {
            myBlure.blurX = 9;//Easy a mathematical equation for easing and adding the Dimension X  degree alpha value for this movie
            myBlure.blurY = 9;//Easy a mathematical equation for easing and adding the Dimension Y  degree alpha value for this movie
    } else {
            myBlure.blurX = 0;//Easy a mathematical equation for easing and adding the Dimension X  degree alpha value for this movie
            myBlure.blurY = 0;//Easy a mathematical equation for easing and adding the Dimension Y  degree alpha value for this movie
    }
    };
}
function showMe() {// show effect function  
    this._visible = true;// enable this movie when this function start
    this.onEnterFrame = function() {// onEnterFrame for this movieClip
        if (this._alpha<100) {// ensure this MovieClip alpha is more less 100% 
            this._alpha += (100-this._alpha)*.25;// Easy a mathematical equation for easing Increase the alpha value for this movie 
            myBlure.blurX += (0-myBlure.blurX)/5;//Easy a mathematical equation for easing and adding the Dimension X  degree alpha value for this movie
            myBlure.blurY += (0-myBlure.blurY)/10;//Easy a mathematical equation for easing and adding the Dimension Y  degree alpha value for this movie
            filters = [myBlure];// assign fillter to this movieClip
        }
        //    
    };
    //end of [showMe] function 
}
function blureThisWin() {// Start the closing Function
    this.onEnterFrame = function() {// onEterFrame function for this movie
        if (this._alpha>0) {//  chicking the Alpha for this movie
            this._alpha += (0-this._alpha)*.25;// Easy a mathematical equation for easing degree the alpha value for this movie 
            this._width += ((myWidth/1.5)-this._width)*.5;//Easy a mathematical equation for easing degree the width value for this movie 
            this._height += ((myHeight/1.5)-this._height)*.5;// Easy a mathematical equation for easing degree the height value for this movie
            myBlure.blurX += (100-myBlure.blurX)/10;//Easy a mathematical equation for easing and adding the Dimension X  degree alpha value for this movie
            myBlure.blurY += (100-myBlure.blurY)/10;//Easy a mathematical equation for easing and adding the Dimension Y  degree alpha value for this movie
            filters = [myBlure];//Executing  Blur filltir to this movie
            trace("Still Rendring!");// this will Execute when onEnterFrame
        } else {
            delete onEnterFrame;// kill this Enterframe event when finish
            _root.add_btn._visible = true;/// visibale the root bottun when this movie show
            this.removeMovieClip;/// remove this from root
            trace("End Rendring! Movie removed");// this will Execute when onEnterFrame ended
        }
    };

}

close_btn.onRelease = function() {// fucntion to the button to call the fucntion
    blureThisWin();/// calling the [closing Function]
};
/// injoy
/// 13/05/2007
//www.akwad.net
// alhumdulleah rab alalmeen 

تبقى لدينا حركة بسيطة جدا ً
وهو عند الضغط على زر السحب نضع هذا الأكشن
طبعا واضح الكود اعتقد وهو عند الضغط والسحب نقوم وظيفة التشويش على النافذه
وعند الانتهاء من السحب يتم اعادة النافذة لشكلها الطبيعي

on (press) {
    _parent.startDrag();
    _parent.onDrage(1)
}
on (release) {
    _parent.stopDrag();
    _parent.onDrage(0)
}
on (releaseOutside) {
    _parent.stopDrag();
    _parent.onDrage(0)
} 

اي سؤال انا حاضر ..
الملف في المرفقات ....
لمشاهدة الاصدار الاخير نفس الصفحة
http://www.akwad.net/useronline/blurWindo_Akwad.html

كل الود

[Zizwar]

كان لدي شك أن مسألة drag سهلة في الفلاش stardrage stopdrag
لقد نزلت الملف وعندما أفتحه في الفلاش يعطيني هذه الرسالة
---------------------------
Flash 8
---------------------------
Unexpected file format.
---------------------------
OK
---------------------------
مع العلم ان الملف المرفق الأول فتح بشكل جيد

[Akwad Net]

اوه بالفعل هذا خطأي
انا لم احفظ الملف بصيغة فلاش 8 بل 9
الحين اغير المرفقات
اعد التحميل عزيزي


----------------
بالنسبة لعمليه السحب ففي الفلاش اسهل بكثير من الجافا
تم اختصار الكثير .. فهي وظيفة داخل الفلاش بالفعل ..
اما ما قمت بوضعه بالجافا فهو يصلح اكثر لعملية تأثير ملاحقة الفأرة

 on (press) {
    _parent.startDrag();
}
on (release) {
    _parent.stopDrag();

}
on (releaseOutside) {
    _parent.stopDrag();
} 

[Flasher]

اشكر الاستاذ "اكواد" على هذا الطرح الجميل... والعمل الحلو


آخخ كم احب هذه اللغة

سويت عمل بسيط محاكي لمافعلت ولكن بالاكشن سكربت 3
للمشاهدة :
http://flasher.ws/uploads/AS3/AS3Windows.html
للتحميل : ( تحتاج Flash CS3)
http://flasher.ws/uploads/AS3/AS3Windows.zip

وهذا هو كلاس النافذة Window الذي صنعته

package com.flasher.draging
{
	
	/*-------------------------------
		Simple dargable window in AS3
		@author Flasher <flasher@flasher.ws>
	---------------------------------*/
	
	/*
		elements classes
	*/
	import flash.display.MovieClip;
	import flash.text.TextField;
	import fl.controls.Button;
	
	/*
		filters
	*/
	import flash.filters.BitmapFilterQuality;
	import flash.filters.BlurFilter;
	import flash.filters.DropShadowFilter;
	
	/*
		Tweener class
	*/
	import caurina.transitions.Tweener;
	
	/*
		MouseEvent class 
	*/
	import flash.events.MouseEvent;
	
	public class Window extends MovieClip
	{
		
		/*
			Constructor
		*/
		
		function Window()
		{
			init();
		}
		
		/*
			initialize 
			@param 		@void
			@return 	@void
		*/
		
		private function init():void
		{
			titleBar.addEventListener(MouseEvent.MOUSE_DOWN, Drag);
			titleBar.addEventListener(MouseEvent.MOUSE_UP  , unDrag );
			titleBar.buttonMode = true;
			
			close.addEventListener(MouseEvent.CLICK,Close);
			btn.addEventListener(MouseEvent.CLICK,Close);
			
			var blurfilter:BlurFilter = new BlurFilter(0, 0, BitmapFilterQuality.HIGH);
			var dshfilter:DropShadowFilter = new DropShadowFilter(4,45,0,1,7,7,.4);
			var myFilters:Array = [blurfilter,dshfilter];
			filters = myFilters;
			
			x += width/2;
			y += height/2
			
			scaleX = .5;
			scaleY = .5;
			
			startBluring();
			Tweener.addTween(this,{scaleX:1,scaleY:1,time:1,transition:"easeoutcubic"});
			stopBluring(1);
			
			label.text = "Testing.....\n Enjoy with AS3!";
		}
		
		/*
			Drag Listener 
			@param 		@MouseEvent
			@return 	@void
		*/
		
		private function Drag(evt:MouseEvent):void
		{
			startDrag();
			startBluring();
		}
		
		/*
			unDrag Listener 
			@param 		@MouseEvent
			@return 	@void
		*/
		
		private function unDrag(evt:MouseEvent):void
		{
			stopBluring();
			stopDrag();
		}
		
		/*
			startBluring
			@param 		@void
			@return 	@void
		*/
		
		private function startBluring():void
		{
			Tweener.addTween(this,{_blur_blurX: 20, time:.25, transition:"easeinexpo"});
		}
		
		/*
			stopBluring
			@param 		@void
			@return 	@void
		*/
		
		private function stopBluring(d:Number=0):void
		{
			Tweener.addTween(this,{_blur_blurX: 0, time:.5, transition:"easeoutcubic",delay:d});
		}
		
		/*
			Close Listener
			@param 		@MouseEvent
			@return 	@void
		*/
		
		public function Close(evt:MouseEvent):void
		{
			startBluring();
			Tweener.addTween(this,{scaleX:.5,scaleY:.5,time:2,transition:"easeoutcubic"});
			Tweener.addTween(this,{alpha:0,time:2.1,transition:"easeoutcubic"});
		}

	}
}

[Akwad Net]

ممتاز جدا ً .. بل رائع ماشا ءالله تبارك الله ..
استخدامك للأكشن سكربت 3 ممتاز جدا ً
الكلاس ممتاز ويحتاج إلى بعض التطوير في ال easing في الحركة لكي يصبح اكثر روعة .
اسجل إعاجبي باجتهادك

دمت بخالص الود استاذي

[Zizwar]

أهلا بالعزيز فلاشر، يا أخ أكواد بدأنا نجمع فريق برمجة أكشن سكريبت اذا وصلنا الى 5 ألأشخاص سنراسل منظمة ecmascript لتدرجنا ضمن قائمتها
ماشاء الله عليك يا أخ فلاشر ممتاز
لكن اشرح لي كيف حللتم عضوية الاخ رياض القرآن << بالمناسبة هو أيضا فلاش ماستر او فلاش مان على وزن سبيدر مان

[Flasher]

اشكركم اخواني جدا... أكواد نت و زيزوار....

صحيح هو يحتاج لقليل من الذوق في اختيار ال Easing... لكن الفكرة هي تطبيق Tween أو حركة على فلتر الBlur
شاكر لك اطلالتك

زيييييزوااار
الله يديم عليك السعادة يارب

لكن اشرح لي كيف حللتم عضوية الاخ رياض القرآن << بالمناسبة هو أيضا فلاش ماستر او فلاش مان على وزن سبيدر مان

بقولك شئ بس لاتعلم احد
أنا من كنت أكتب بعضوية رياض القرآن والمواضيع التي تخص الفلاش والبرمجة كلها تعود الي
فلذلك حللت عضويته مسكين

[Akwad Net]

ماشاء الله ماشاء الله مجتمعين العباقرة في موضوعي
وش تسوون ها ؟؟ تسولفون ؟؟

صحيح يحتاج بعض التطوير فقط ولكن فعلا اهنيك على استخدامك اكشن سكربت 3
بس صحيح يا زيزوار نندرج تحت القائمة عندهم وش نسوي

[سالم العليلي]

اسجل اعجابي ... لهذا الموضوع ... وللكتّاب ايضاً ....
بارك الله فيكم ... وجزاكم الله الف خير ... وجزى من أنجبكم الفردوس الأعلى

[Zizwar]

ماشاء الله ماشاء الله مجتمعين العباقرة في موضوعي
وش تسوون ها ؟؟ تسولفون ؟؟

صحيح يحتاج بعض التطوير فقط ولكن فعلا اهنيك على استخدامك اكشن سكربت 3
بس صحيح يا زيزوار نندرج تحت القائمة عندهم وش نسوي

لم نكن نقول شيئا، أين ؟؟؟ <<< يخشى من الباند

ecma هي منظمة أوربية مثلها مثل منظمة w3s غير أن اكما تهتم بوضع معايير قياسية للبرمجة ك C# و في معايير ecmascript ك javascript و jscript و actionscript رغم أن الإصدار الأخير من أكشن بدأ يهرب من المعايير القياسية لل ecmascript
اذا كنا فريق يمكن أن نكون موقع عربي يهتم بهذه المعايير معتمد من الموقع الأصلي

[Zizwar]

اسجل اعجابي ... لهذا الموضوع ... وللكتّاب ايضاً ....
بارك الله فيكم ... وجزاكم الله الف خير ... وجزى من أنجبكم الفردوس الأعلى

نحن من لنا الشرف بمروركم

[عافور]

ما شا ءالله اتمنى اني اوصل لهذا المستوى في برمجة الاكشن سكربت بارك الله فيكم يا احباب

[Zizwar]

ما شا ءالله اتمنى اني اوصل لهذا المستوى في برمجة الاكشن سكربت بارك الله فيكم يا احباب

ان شاء الله تصل الى الأفضل